package Algorithm::CheckDigits::M11_002;

use 5.006;
use strict;
use warnings;
use integer;

our @ISA = qw(Algorithm::CheckDigits);

sub new {
	my $proto = shift;
	my $type  = shift;
	my $class = ref($proto) || $proto;
	my $self  = bless({}, $class);
	$self->{type} = lc($type);
	return $self;
} # new()

sub is_valid {
	my ($self,$number) = @_;
	if ($number =~ /^(.+)(.)$/) {
		return uc($2) eq $self->_compute_checkdigit($1);
	}
	return ''
} # is_valid()

sub complete {
	my ($self,$number) = @_;
	if ($number =~ /^[0-9]+$/) {
		my $cd = $self->_compute_checkdigit($number);
		return $number . $cd unless 0 > $cd;
	}
	return '';
} # complete()

sub basenumber {
	my ($self,$number) = @_;
	if ($number =~ /^(.+)(.)$/) {
		return $1 if (uc($2) eq $self->_compute_checkdigit($1));
	}
	return '';
} # basenumber()

sub checkdigit {
	my ($self,$number) = @_;
	if ($number =~ /^(.+)(.)$/) {
		return $2 if (uc($2) eq $self->_compute_checkdigit($1));
	}
	return '';
} # checkdigit()

sub _compute_checkdigit {
	my $self   = shift;
	my $number = shift;

	if ($number =~ /^[-0-9]+$/) {

		$number =~ s/-//g;
		my @digits = split(//,$number);
		my $sum    = 0;
		my $weight = 2;

		for (my $i = 0; $i <= $#digits; $i++) {

			$sum += $weight * $digits[$i];
			++$weight;

		}
		$sum %= 11;
		return 10 == $sum ? -1 : $sum;
	}
	return -1;
} # _compute_checkdigit()

# Preloaded methods go here.

1;
__END__

=head1 NAME

CheckDigits::M11_002 - compute check digits for PZN (DE)

=head1 SYNOPSIS

  use Algorithm::CheckDigits;

  $pzn = CheckDigits('pzn');

  if ($pzn->is_valid('4877800')) {
	# do something
  }

  $cn = $pzn->complete('487780');
  # $cn = '4877800'

  $cd = $pzn->checkdigit('4877800');
  # $cd = '0'

  $bn = $pzn->basenumber('4877800');
  # $bn = '487780'
  
=head1 DESCRIPTION

=head2 ALGORITHM

=over 4

=item 1

From left to right beginning with the first position all digits are
multiplied with 2,3,4,...

=item 2

The sum of all products is computed.

=item 3

The checkdigit ist the sum of step 2 taken modulo 11.

=item 4

If the checkdigit is '10' the whole number is not taken as a PZN.

=back

=head2 METHODS

=over 4

=item is_valid($number)

Returns true only if C<$number> consists solely of numbers and the last digit
is a valid check digit according to the algorithm given above.

Returns false otherwise,

=item complete($number)

The check digit for C<$number> is computed and concatenated to the end
of C<$number>.

Returns the complete number with check digit or '' if C<$number>
does not consist solely of digits and spaces.

=item basenumber($number)

Returns the basenumber of C<$number> if C<$number> has a valid check
digit.

Return '' otherwise.

=item checkdigit($number)

Returns the checkdigit of C<$number> if C<$number> has a valid check
digit.

Return '' otherwise.

=back

=head2 EXPORT

None by default.

=head1 AUTHOR

Mathias Weidner, E<lt>mathias@weidner.in-bad-schmiedeberg.deE<gt>

=head1 SEE ALSO

L<perl>,
L<CheckDigits>,
F<www.pruefziffernberechnung.de>.

=cut