MRAMBERG / Catalyst-View-HTML-Template-0.03 / lib / Catalyst / View / HTML / Template.pm 

            

              
1
2
3
4
5
6
7
8
—
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
—
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
—
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141

              
package Catalyst::View::HTML::Template;
use strict;
use base 'Catalyst::View';
use HTML::Template;
our $VERSION = '0.03';
=head1 NAME
Catalyst::View::HTML::Template - HTML::Template View Class
=head1 SYNOPSIS
    # use the helper
    create.pl view HTML::Template HTML::Template
    # lib/MyApp/View/HTML/Template.pm
    package MyApp::View::HTML::Template;
    use base 'Catalyst::View::HTML::Template';
    __PACKAGE__->config(
        die_on_bad_params => 0,
        file_cache        => 1,
        file_cache_dir    => '/tmp/cache'
    );
    1;
    # Meanwhile, maybe in an 'end' action
    $c->forward('MyApp::View::HTML::Template');
=head1 DESCRIPTION
This is the C<HTML::Template> view class. Your subclass should inherit from this
class.
=head2 METHODS
=over 4
=item process
Renders the template specified in C<< $c->stash->{template} >> or C<<
$c->request->match >>.
Template params are set up from the contents of C<< $c->stash >>,
augmented with C<base> set to C<< $c->req->base >> and C<name> to 
C<< $c->config->{name} >>.  Output is stored in C<< $c->response->body >>.
=cut
sub process {
    my ( $self, $c ) = @_;
    my $filename = $c->stash->{template} || $c->req->match;
    my $body = $self->render($c,$filename);
    unless ( $c->response->headers->content_type ) {
        $c->res->headers->content_type('text/html; charset=utf-8');
    }
    $c->response->body($body);
    return 1;
}
=item render
Renders the given template and returns output. Template params are set up
either from the contents of  C<%$args> if $args is a hashref, or C<< $c->stash >>,
augmented with C<base> set to C<< $c->req->base >> and C<name> to
C<< $c->config->{name} >>.
=cut
sub render {
    my ( $self, $c, $filename, $args ) = @_;
    unless ($filename) {
        $c->log->debug('No template specified for rendering') if $c->debug;
        return 0;
    }
    my %options = (
        cache    => 1,
        filename => $filename,
        path     => [ $c->path_to('root'), $c->path_to('root','base') ],
    );
    $c->log->debug(qq/Rendering template "$filename"/) if $c->debug;
    my $template = HTML::Template->new( %options, %{ $self } );
    my $template_params = $args && ref($args) eq 'HASH' ? $args : $c->stash;
    $template->param(
        base => $c->req->base,
        name => $c->config->{name},
        %$template_params
    );
    my $output;
    eval { $output = $template->output };
    if ( my $error = $@ ) {
        chomp $error;
        $error = qq/Couldn't render template "$filename". Error: "$error"/;
        $c->log->error($error);
        $c->error($error);
        return 0;
    }
    return $output;
}
=item config
This allows your view subclass to pass additional settings to the
HTML::Template config hash.
=back
=head1 SEE ALSO
L<HTML::Template>, L<Catalyst>, L<Catalyst::Base>.
=head1 AUTHOR
Christian Hansen, C<ch@ngmedia.com>
=head1 COPYRIGHT
This program is free software, you can redistribute it and/or modify it
under the same terms as Perl itself.
=cut
1;